on adding folder items to this_folder after receiving these_items
	
	-- transform alias to posix path that Transmit can use
	set these_items_string to these_items as string
	set the_file to the POSIX path of file these_items_string
	
	-- list categories in yer blog
	-- line break for display purposes
	-- i only have a few sub-cateogories so i don't mind typing them each time
	display dialog ("Post to sub-category? Choices are:
		different
		blosxom
		blog
		categories
		no (for root level)") default answer "no"
	set category to text returned of the result as string
	
	-- set path on server
	if (category is equal to "no") then
		set remote_path to "path/to/datadir"
	else
		set remote_path to "path/to/datadir/" & category as string
	end if
	
	-- enter password
	-- again line breaks for display
	display dialog ("Connecting to " & remote_path & "?

Enter password:") default answer ""
	set my_password to text returned of the result as string
	
	-- Transmit happens	
	tell application "Transmit"
		activate
		make new document at before front document
		tell document 1
			if (connect to "ftp.yoursite.com" as user "your_username" with password my_password) then
				if (set their stuff to remote_path) then
					upload item the_file
				else
					display dialog ("could not set their stuff") buttons {"OK"}
				end if
			else
				display dialog ("could not connect to server") buttons {"OK"}
			end if
		end tell
		close document 1
	end tell
	
end adding folder items to